From Ren'Py Visual Novel Engine

Contents 1 New CG Gallery 1.1 Example 1.2 Documentation 1.2.1 Conditions 1.2.2 Convenience 1.2.3 Customization 1.2.4 Styles

New CG Gallery

This page is obsolete; see http://www.renpy.org/doc/html/rooms.html instead.

This is a rewritten CG gallery, supporting more sophisticated forms of unlocking. To use it, download new_gallery.rpy, and add it to your game directory. You'll then need to create a Gallery object, and call the show() method on it, after configuring the gallery and adding buttons. This is often done inside a single label, which can be added to config.main_menu.

This requires 6.6.0 or later (not in compat-mode) to run.

Example

init:
    # Position the navigation on the right side of the screen.
    $ style.gallery_nav_frame.xpos = 800 - 10
    $ style.gallery_nav_frame.xanchor = 1.0
    $ style.gallery_nav_frame.ypos = 12

    # Add the gallery to the main menu.
    $ config.main_menu.insert(2, ('Gallery', "gallery", "True"))

# The entry point to the gallery code.
label gallery:
    python hide:

        # Construct a new gallery object.
        g = Gallery()

        # The image used for locked buttons.
        g.locked_button = "gallery_locked.png"

        # The background of a locked image.
        g.locked_background = "gallery_lockedbg.jpg"

        # Frames added over unlocked buttons, in hover and idle states.
        g.hover_border = "gallery_hover.png"
        g.idle_border = "gallery_idle.png"

        # An images used as the background of the various gallery pages.
        g.background = "gallery_background.jpg"

        # Lay out the gallery images on the screen.
        # These settings lay images out 3 across and 4 down.
        # The upper left corner of the gird is at xpos 10, ypos 20.
        # They expect button images to be 155x112 in size.
        g.grid_layout((3, 4), (10, 12), (160, 124))

        # Show the background page.
        g.page("Backgrounds")

        # Our first button is a picture of the beach.
        g.button("thumb_beach.jpg")
        #
        # These show images, if they have been unlocked. The image name must
        # have been defined using an image statement.
        g.unlock_image("bg beach daytime")
        g.unlock_image("bg beach nighttime")
        #
        # This shows a displayable...
        g.display("beach_sketch.jpg")
        # ... if all prior images have been show.
        g.allprior()

        # A second set of images.
        g.button("thumb_lighthouse.jpg")
        g.unlock_image("bg lighthouse day")
        g.unlock_image("bg lighthouse night")
        g.display("lighthouse_sketch.jpg")
        g.allprior()



        # We can use g.page to introduce a second page.
        g.page("Characters")

        g.button("thumb_eileen.jpg")
        #
        # Note that we can give image and unlock image more than one image
        # at a time.
        g.unlock_image("bg lighthouse day", "eileen day happy")
        g.unlock_image("bg lighthouse day", "eileen day mad")



        # Another page, this one for concept art.
        g.page("Concept Art")

        g.button("thumb_concepts.jpg")
        #
        # We can apply conditions to buttons as well as to images.
        # The "condition" condition checks an arbitrary expression.
        g.condition("persistent.beat_game")
        #
        g.display("concept1.jpg")
        g.display("concept2.jpg")
        g.display("concept3.jpg")


        # Now, show the gallery.
        g.show()

    return

Documentation

Function:

Gallery

():

Method:

Gallery.page

(name, background=None):

Method:

Gallery.button

(idle, hover=None, locked=None, **properties):

Method:

Gallery.image

(*images):

Method:

Gallery.display

(displayable):

Method:

Gallery.show

(page=0):

Conditions

Conditions can be assigned to buttons or images in the gallery. Conditions are added to the last button or image defined. A button is unlocked if all of its conditions are satisfied and at least one of its images is unlocked. An image is unlocked if all of its conditions are satisfied.

Method:

Gallery.unlock

(*images):

Method:

Gallery.condition

(expr):

Method:

Gallery.allprior

():

Convenience

Method:

Gallery.unlock_image

(*images):

Customization

Customization can be performed by setting fields on the gallery object.

layout - A function that takes two arguments, a 0-based button number and the number of buttons on the current page. It's expected to return a dictionary giving the placement properties for the numbered button.

The default layout function returns an empty dictionary, requiring buttons to be placed by hand.

Method:

Gallery.grid_layout

(gridsize, upperleft, offsets):

navigation - A function that is called with three arguments: The name of the current page, the 0-based number of the current page, and the total number of pages. This function should add ui elements to the screen that cause ui.interact to return either ("page", page_num), where page_num is the page that the user should next see, or ("return", 0), to cause Gallery.show to return.

The default navigation shows a frame containing buttons for each page, and one "Return" button.

locked_button - A displayable that is shown when a button is locked.

locked_image - A function that is called with two arguments: A 0-based image number, and the number of images in the current button. It is responsible for indicating to the user that the current image is locked. It should not cause an interaction to occur.

The default locked_image shows locked_background to the user, along with the words "Image number of number in page is locked.", where number is the 1-based number of the image.

locked_background - Used by the default locked_image, a background image that is displayed by a locked image.

idle_border - A displayable that is shown by an unfocused button when no hover parameter is given for that button.

hover_border - A displayable that is shown by a focused button when no hover parameter is given for that button.

transition - A transition that is used when showing gallery pages and gallery images.

Styles

The following styles are used by the default navigation function.

style.gallery_nav_frame (inherits from style.frame)

The style of the frame holding the gallery navigation. Use this to customize the look of the frame, and also to move the frame around on the screen.

style.gallery_nav_vbox (inherits from style.vbox)

The style of the vbox holding the gallery navigation functions.

style.gallery_nav_button (inherits from style.button)

The style of a gallery navigation button.

style.gallery_nav_button_text (inherits from style.button_text)

The style of the text of a gallery navigation button.